;;Dimensionality: 4
;;Experiment: KGST
;;Phaseoverlap: 00000
;;trosy: 0
;;DimProjections: 2
;;Hfreq: BF1
;;Cfreq: BF2
;;Nfreq: BF3
;;Carrier1: O1P
;;Carrier2: O2P
;;Carrier3: O2P
;;Carrier4: O1P
;;----------------end header------------------

;conventional name: 4D APSY-HCCH-COSY
;Rosmarie Joss, Sebastian Hiller, ETH Zurich 2007

;two constant time elements for transfer HC -> C and back
;15N decoupling by Waltz
;carbonyl decoupling by shaped pulse with offset

;pl1   : power for 1H hard pulse
;pl2   : power for 13C hard pulse
;pl3   : not used - set to 120 dB
;pl9   : power for presat 1H
;pl12  : power for 13C GARP decoupling
;pl13  : power for 15N WALTZ decoupling
;sp2   : power for p11 water flip down
;sp3   : power for 13CO decoupling p13

;p1    : 90 degree hard pulse 1H
;p2    : 180 degree 1H
;p3    : 90 degree hard pulse 13C
;p4    : 180 degree 13C
;pcpd3 : 90 degree cpd-pulse 15N (WALTZ, 160us) 
;p13   : 180 13CO off-reson pulse 
;p11   : shaped pulse - water flip down
;p12   : spin lock before aquisition

;p21   : 600u 
;p22   : 1500u 
;p23   : 400u 
;p24   : 1000u  
;p25   : 1000u 
;p26   : 800u

;gpz1  : 47 %
;gpz2  : 70 %
;gpz3  : 40 %
;gpz4  : 70 %
;gpz5  : 70 %
;gpz6  : 50 %

;d1    : relaxation delay
;d18   : Inept 13C-H set to 1.6m

;cnst1: alpha
;cnst2: beta

;cnst21: SW1 (H) [Hz]
;cnst22: SW2 (C) [Hz]
;cnst23: SW3 (C) [Hz]

"cnst21=cnst21"
"cnst22=cnst22"
"cnst23=cnst23"

;cnst8: CO chemical shift (offset, in ppm)

#include <Avance.incl>

define loopcounter ST1CNT
"ST1CNT = td1 / (2)"

define delay INEPT
define delay INEPT1

#define GRADIENT1  10u p21:gp1 290u
#define GRADIENT2  10u p22:gp2 590u
#define GRADIENT3  10u p23:gp3 190u
#define GRADIENT4  10u p24:gp4 190u
#define GRADIENT5  10u p25:gp5 190u
#define GRADIENT6  10u p26:gp6 190u

"cnst10=abs(sin(0.017453293*cnst1))"
"cnst11=abs(cos(0.017453293*cnst1))"
"cnst12=abs(sin(0.017453293*cnst2))"
"cnst13=abs(cos(0.017453293*cnst2))"

"d0 = 1.0m"     ; dummy
"in0= in1"      ; dummy

"p2=2*p1"
"p4=2*p3"

"spoff2=0"
"spoff3=bf2*(cnst8/1000000)-o2"

;----------------------fixed delays

"INEPT=d18-(p26+200u)"

;----------------------------indirect dimensions


;----------------------H

"d3=d18-(200u+p23)"
"d30=5u"
"d31=d18-(200u+p23)+9u+4*p3"

"in3=cnst12*in1"
"in31=2*d31/td1"
"in30=0u"

;----------------------C1

"d4=10u"
"d7=1.1m-p13"
"d5=2.8m"
"d6=3.9m+p2-p13"

"in4=cnst10*cnst13*in1"
"in6=in4"



;----------------------C2

"d24=10u"
"d27=1.1m-p13"
"d25=2.8m"
"d26=3.9m+p2-p13"

"in24=cnst11*cnst13*in1"
"in26=in24"

"l1=(d6/(2*in6+0.1u))*4"
"l2=(d26/(2*in26+0.1u))*4"
"l3=l1+l2"

1  100u ze
#ifdef W
   1m ip1
#endif
#ifdef X
   1m ip2
#endif
#ifdef Y
   1m ip3
#endif
#ifdef A2
   1m ip31
   1m ip31
#endif
;------------------------------------Switch constant-time for 15N
if "in31 < in3" goto 5
   10u
   "in31=in3"
   10u
goto 6
5  1m
   10u
  "in30=in3-in31"
   10u
6  1m
;-----------------------------------------
2  10m
   LBLSTS1, 5m
   LBLF1, 5m
   10u do:f2
   10u do:f3
   100u LOCKH_OFF
   10u pl2:f2
   10u pl9:f1
   10u pl13:f3
   d1 cw:f1
   10u do:f1
   50u fq=cnst7 (bf ppm):f1
   10u pl1:f1
   100u LOCKH_ON
;-----------------------------------------water treatment
   GRADIENT1
;   (p11:sp2 ph19:r):f1
;   GRADIENT2
;-----------------------------------------semi-ct 
   (p1 ph1):f1
   GRADIENT3
   d3
   (p3 ph20 2u p4 ph21 2u p3 ph20):f2
   d30
   (p2 ph20):f1
   GRADIENT3
   d31
   (p1 ph8):f1 
;-----------------------------------------z-Filter
   10u
   10u fq=0:f1
   10u
   10u pl1:f1
   GRADIENT4
;-----------------------------------------first ct
   40u cpd3:f3
   (p3 ph2):f2
   d4
   (p13:sp3 ph20):f2
   5u
   5u pl2:f2
   d7
   (p2 ph20):f1
   d5
   (p4 ph20):f2
   d6
   (p13:sp3 ph20):f2
   5u
   5u pl2:f2
   10u
   (refalign (p3 ph20):f2 center (p1 ph20):f1)
;-----------------------------------------second ct
   d24
   (p13:sp3 ph20):f2
   5u 
   5u pl2:f2
   d27
   (p2 ph20):f1
   d25
   (p4 ph20):f2
   d26
   (p13:sp3 ph20):f2
   5u 
   5u pl2:f2
   10u
   (p3 ph3):f2
;-----------------------------------------z-Filter
   10u do:f3
   GRADIENT5
;-----------------------------------------INEPT
   (p1 ph20):f1 
   GRADIENT6
   INEPT
   (refalign (p2 ph20):f1 center (p3 ph20 2u p4 ph21 2u p3 ph20):f2)
   GRADIENT6
   INEPT pl12:f2
;-----------------------------------------acquisition
   (p12 ph20):f1
   go=2 ph31 cpd2:f2
#ifdef Pw
   1m do:f2 wr #0 if #0 zd ip1
#endif
#ifdef Px
   1m do:f2 wr #0 if #0 zd ip2
#endif
#ifdef Py
   1m do:f2 wr #0 if #0 zd ip3
#endif
   lo to LBLSTS1 times 2
   1m id3 
   1m id30 
   1m dd31
   1m id4 
   1m dd6
   1m id24 
   1m dd26
   lo to LBLF1 times ST1CNT
   10u do:f1
   10u do:f2
   10u do:f3
   10u LOCKH_OFF
exit

;-------------------phases for phasecycle

ph8=1 1 3 3

;-------------------water supression

ph19=0

;-------------------fixed phases

ph20=0
ph21=1
ph22=2
ph23=3

;-------------------phases for States-TPPI

ph31= 0 2 2 0

ph1=0
ph2=0
ph3=0 2