;;Dimensionality: 5
;;Experiment: ICONH
;;Phaseoverlap: 00000
;;trosy: 0
;;DimProjections: 2
;;Hfreq: BF1
;;Cfreq: BF2
;;Nfreq: BF3
;;Carrier1: CNST 7
;;Carrier2: CNST 18
;;Carrier3: CNST 16
;;Carrier4: O3P
;;Carrier5: O1P
;;----------------end header------------------

;Conventional name: 5D APSY-HC(CC)-TOCSY-CO-NH

;Rosmarie Joss, Sebastian Hiller, ETH Zurich 2007

;pl1   : plevel for hard 1H 90 pulse p1
;pl11  : plevel for 1H-dipsi2 (pcpd1:~80u)
;pl3   : plevel for hard 15N 90 pulse p5
;pl2   : plevel for hard 13C 90 pulse p3
;pl12  : plevel for hard 13C 180 pulse p4
;pl14  : plevel for hard 13C 90 pulse p7 & p8
;pl15  : plevel for spinlock pulse p27 & isotropic mixing
;pl4   : plevel for 2H decoupling on 4th channel
;pl13  : plevel for 15N decoupling

;p1    : 90 1H pulse
;p5    : 90 15N pulse
;p3    : 90 13Caliph pulse: SQRT(15)/(DeltaOmegaHz[CbCa,C']*4), 47u for 600 MHz
;p4    : 180 13C pulse: SQRT(3)/(DeltaOmegaHz[CbCa,C']*2), 42u for 600 MHz
;p7    : 90 13C pulse: SQRT(15)/(DeltaOmegaHz[Ca,C']*4), 53u for 600MHz
;p9    : TOCSY mixing in 13C (~31 us)
;p27   : Spinlock pulse
;pcpd1 : Pulse length for 1H dec.
;pcpd3 : Pulse length for 15N dec. (~160u)
;pcpd4 : Pulse length for 2H dec.
;cpdprg1: 1H decoupling (WALTZ)
;cpdprg3: 15N decoupling during AQ (WALTZ)
;cpdprg4: 2H decoupling (optional)

;p21   : 800u gradient in INEPT_1 (with gp1:35%)
;p22   : 800u Z-Filter betw. H/C(al) transfer (with gp2:55%)
;p23   : 800u Z-Filter betw. CA/CO transfer (with gp3:5%)
;p24   : 800u Z-Filter betw. CO/N transfer (with gp4:10%)
;p25   : 800u Gradient in N/HN INEPT (with gp5:50%)
;p26   : 800u Gradient in WG (with gp6:25%)
;p28   : 800u Gradient in CO/N (with gp8:28%)
;p29   : 400u Gradient in Cali (with gp9:32%)


;gpz1  : 35%
;gpz2  : 55%
;gpz3  : 30%
;gpz4  : 40%
;gpz5  : 50%
;gpz6  : 65%
;gpz8  : 28%
;gpz9  : 32%

;cnst1: alpha
;cnst2: beta
;cnst3: gamma

;cnst41: SW1 (H) [Hz]
;cnst42: SW2 (C) [Hz]
;cnst43: SW3 (CO)[Hz]
;cnst44: SW4 (N) [Hz]

"cnst41=cnst41"
"cnst42=cnst42"
"cnst43=cnst43"
"cnst44=cnst44"

;p10   : CAli G3 pulse (180u for 750DRX)
;sp5   : plevel for CAli (shape: GaussCascadeG3)
;spnam5: CAli pulse G3 (GaussCascadeG3)
;spoff5 : 0 Hz

;p12   : CAli pulse (180us for DRX750)
;sp6   : plevel for CAli pulse (shape: GaussCascadeQ3)
;spnam6: CAli pulse Q3 (GaussCascadeQ3)
;spoff6 : 0 Hz

;p14   : CA-CO Multiband pulse
;sp7   : plevel for CA-CO multiband pulse
;spnam7: CA-CO multiband pulse (pulse_x)
;spoff7 : 0 Hz

;p15   : 180 13CO off-reson pulse 120/100/80 us (for DRX500/DRX600/DRX750)
;sp8   : plevel for pulse p15 (shape: gauss128_5)
;spnam8: CO offres pulse (gauss128_5)
;spoff8: DeltaOmegaHz[CaCb, C'] ~ BF2 * 137

;p16   : 180 13Ca off-reson pulse ././220 us (for DRX500/DRX600/DRX750)
;spnam2: Ca offres. pulse (iburp1_128)
;sp2   : plevel for pulse p16 (shape: iburp1_128)
;spoff2 : DeltaOmegaHz[C',Ca] ~ - BF2 * 123

;cnst16 : CO chemical shift [175ppm]
;cnst17 : CA chemical shift [55ppm]
;cnst18 : (o2p) C(aliph) chemical shift [38ppm!](optimized for methyl groups)
;cnst7  : Carrier H-side chain [2.5ppm]

;set o2p to 38ppm

;phcor6 : -10 degree

;d2    : 1H-15N inept delay (2.5ms)
;d3    : 1H-13C inphase delay (1.1ms)
;d5    : delay for 1H in-phase coh (5.5ms)
;d6    : delay for 1H in-phase coh (2.3ms) 
;d7    : 13Cab-13CO inept delay (3.7ms)
;d8    : 13Ca-13CO inept delay (4.5ms)
;d9    : 13CO-15N inept delay (11.4ms)
;d12   : 1/2 constant-time 15N (11ms-14ms)
;d18   : TOCSY mixing Time (~21 ms)
;d22   : Delay for 3-9-19=1/(Hz between nulls) 200/166/130u (for DRX500/DRX600/DRX750)
;d1    : interscan delay
;d14   : 1/2 constant-time 13C (3.3m)
;in0   : increment 15N dimension
;in10  : increment 13C dimension

define delay IN_CCO
define delay INEPT_W
define delay WG_1

#define GRADIENT1  10u p21:gp1 200u
#define GRADIENT2  10u p22:gp2 200u   ;IzSz
#define GRADIENT3  10u p23:gp3 200u   ;IzSz
#define GRADIENT4  10u p24:gp4 200u   ;IzSz
#define GRADIENT5  10u p25:gp5 200u   ;IzSz
#define GRADIENT6  10u p26:gp6 200u
#define GRADIENT8  10u p28:gp8 200u
#define GRADIENT9  10u p29:gp9 200u

"IN_CCO=d7-p14*0.5"
"WG_1=d22/2-p5"
"INEPT_W=d2-(p26+210u+p1*2.3846+d22*2.5)"

;"l1=d18/(217.3*p9+144u)"

"p2=2*p1"
"p3=968000/(bf2*(cnst16-cnst18))"
"p4=866000/(bf2*(cnst16-cnst18))"
"p6=2*p5"
"p7=968000/(bf2*(cnst16-cnst17))"
"p8=2*p7"

"cnst10=abs(sin(0.017453293*cnst1))"
"cnst11=abs(cos(0.017453293*cnst1))"
"cnst12=abs(sin(0.017453293*cnst2))"
"cnst13=abs(cos(0.017453293*cnst2))"
"cnst14=abs(sin(0.017453293*cnst3))"
"cnst15=abs(cos(0.017453293*cnst3))"

"spoff8=bf2*((cnst16-cnst18)/1000000)"    ;CO-C(aliph)
"spoff2=(bf2*((cnst17-cnst16)/1000000))"  ;CA-CO
"spoff7=0"

;cnst51 : set to cnst 7
;cnst52 : set to cnst 18
;cnst53 : set to cnst 16
;cnst54 : set to o3p
;cnst55 : set to o1p

"cnst51=cnst51"
"cnst52=cnst52"
"cnst53=cnst53"
"cnst54=cnst54"
"cnst55=cnst55"

;------------------------------indirect dimensions

;----------------------------delays for 1H evolution

"d19=1.7m-p10-10u"
"d16=10u"
"d17=1.7m"

"in19=cnst14*in1*0.5"
"in17=((d17-10u)/td1)*2"
"in16=0u"

;----------------------------delays for 13Cali evolution

"d4=1.1m-20u-p2-p15-p29-200u"
"d20=10u"
"d26=10u"
"d27=1.1m-p15+0.637*p3-p29-200u"

"in20=cnst15*cnst12*in1*0.5"
"in27=((d27-10u)/td1)*2"
"in26=0u"

;----------------------------delays for 13CO evolution

"d8=4.5m"
"d11=d9-d8-p6-p16-p28-200u"
"d13=10u"
"d15=d9-p16-p28-200u"

"in8=cnst15*cnst13*cnst10*in1*0.5"
"in15=((d15-10u)/td1)*2"
"in13=0u"

;----------------------------delay for 15N evolution

"d30=d12"
"d29=5u"
"d21=d12-5u-p8"
"d28=d12-5u-p8-5u-p16"
"d31=d12-5u-p8-2*d2"

"in21=cnst11*cnst13*cnst15*in1*0.5"
"in31=in21"
"in30=((d30-20u)/td1)*2"
"in29=0u"

;------------------------------

#include <Avance.incl>

define loopcounter ST1CNT
"ST1CNT = td1 / (2)"


1  10u ze
#ifdef V
	1m ip1
#endif
#ifdef W
	1m ip2
#endif
#ifdef X
	1m ip5
#endif
#ifdef Y
	1m dp11
#endif
#ifdef A2
   1m ip31
   1m ip31
#endif
   goto 9
   10u id15
   10u id30
   10u id31
   10u id21
   10u id19
   10u id17
   10u id20
   10u id27
   10u id8
9  5m
;------------------------------------Switch constant-time for 1H
if "in17 < in19" goto 5
   10u
   "in17=in19"
   10u
goto 6
5  1m
   10u
  "in16=in19-in17"
   10u
6  1m
;------------------------------------Switch constant-time for 13C
if "in27 < in20" goto 3
   10u
   "in27=in20"
   10u
goto 4
3  1m
   10u
  "in26=in20-in27"
   10u
4  1m
;------------------------------------Switch constant-time for 13CO
if "in15 < in8" goto 11
   10u
   "in15=in8"
   10u
goto 12
11  1m
   10u
  "in13=in8-in15"
   10u
12  1m
;------------------------------------Switch constant-time for 15N
if "in30 < in21" goto 7
   10u
   "in30=in21"
   10u
goto 8
7  1m
   10u
  "in29=in21-in30"
   10u
8  1m
;--------------------------------------------------	
2  10m
   LBLSTS1, 5m
   LBLF1, 5m
   10u do:f3
   10u LOCKH_OFF
   d1
   10u LOCKH_ON
   20u fq=cnst18(bf ppm):f2
   10u
   20u fq=cnst7(bf ppm):f1
   10u
   10u pl1:f1
   10u pl3:f3
   10u pl12:f2
;-------------------------------------------- semi-ct on H
   (p1 ph1):f1
   d19       
   (p10:sp5 ph20):f2
   d16
   (p2 ph20):f1
   d17 pl2:f2
   (p1 ph8):f1
;-------------------------------------------- z filter
   GRADIENT2
   10u fq=0:f1
   10u
   10u pl1:f1
;-------------------------------------------- semi ct-evolution on 13ca inphase H-C
   (p3 ph2):f2
   d20
   (p15:sp8 ph20):f2 (p6 ph20):f3
   5u
   d4
   GRADIENT9
   (p2 ph20):f1
   d26
   5u 
   5u
   (p12:sp6 ph20):f2
   5u
   GRADIENT9
   d27
   (p15:sp8 ph20):f2 (p6 ph20):f3
   5u
   5u pl15:f2  
;-------------------------------------------- mixing period
   (p1 ph21):f1 (p27 ph20 2u):f2          ;spin lock
10 (p9*2.722 ph23):f2     ;DIPSI-3
   2u pl11:f1
   (p9*4.389 ph21 2u):f2     ;18 steps * 4 (0 2 2 0)-supercyclesteps = 72 steps
   (p9*2.778 ph23 2u):f2
   (p9*3.056 ph21 2u):f2
   (p9*0.333 ph23 2u):f2
   (p9*2.556 ph21 2u):f2
   (p9*4.000 ph23 2u):f2
   (p9*2.722 ph21 2u):f2
   (p9*4.111 ph23 2u):f2
   (p9*3.778 ph21 2u):f2
   (p9*3.889 ph23 2u):f2
   (p9*2.889 ph21 2u):f2
   (p9*3.000 ph23 2u):f2
   (p9*0.333 ph21 2u):f2
   (p9*2.500 ph23 2u):f2
   (p9*4.050 ph21 2u):f2
   (p9*2.830 ph23 2u):f2
   (p9*4.389 ph21 2u):f2

   (p9*2.722 ph21 2u):f2
   (p9*4.389 ph23 2u):f2
   (p9*2.778 ph21 2u):f2
   (p9*3.056 ph23 2u):f2
   (p9*0.333 ph21 2u):f2
   (p9*2.556 ph23 2u):f2
   (p9*4.000 ph21 2u):f2
   (p9*2.722 ph23 2u):f2
   (p9*4.111 ph21 2u):f2
   (p9*3.778 ph23 2u):f2
   (p9*3.889 ph21 2u):f2
   (p9*2.889 ph23 2u):f2
   (p9*3.000 ph21 2u):f2
   (p9*0.333 ph23 2u):f2
   (p9*2.500 ph21 2u):f2
   (p9*4.050 ph23 2u):f2
   (p9*2.830 ph21 2u):f2
   (p9*4.389 ph23 2u):f2
  
   (p9*2.722 ph21 2u):f2
   (p9*4.389 ph23 2u):f2
   (p9*2.778 ph21 2u):f2
   (p9*3.056 ph23 2u):f2
   (p9*0.333 ph21 2u):f2
   (p9*2.556 ph23 2u):f2
   (p9*4.000 ph21 2u):f2
   (p9*2.722 ph23 2u):f2
   (p9*4.111 ph21 2u):f2
   (p9*3.778 ph23 2u):f2
   (p9*3.889 ph21 2u):f2
   (p9*2.889 ph23 2u):f2
   (p9*3.000 ph21 2u):f2
   (p9*0.333 ph23 2u):f2
   (p9*2.500 ph21 2u):f2
   (p9*4.050 ph23 2u):f2
   (p9*2.830 ph21 2u):f2
   (p9*4.389 ph23 2u):f2
  
   (p9*2.722 ph23 2u):f2
   (p9*4.389 ph21 2u):f2
   (p9*2.778 ph23 2u):f2
   (p9*3.056 ph21 2u):f2
   (p9*0.333 ph23 2u):f2
   (p9*2.556 ph21 2u):f2
   (p9*4.000 ph23 2u):f2
   (p9*2.722 ph21 2u):f2
   (p9*4.111 ph23 2u):f2
   (p9*3.778 ph21 2u):f2
   (p9*3.889 ph23 2u):f2
   (p9*2.889 ph21 2u):f2
   (p9*3.000 ph23 2u):f2
   (p9*0.333 ph21 2u):f2
   (p9*2.500 ph23 2u):f2
   (p9*4.050 ph21 2u):f2
   (p9*2.830 ph23 2u):f2
   (p9*4.389 ph21 2u):f2
   lo to 10 times l1   
;-------------------------------------------- inept 13cab13co
   5u
   5u cpds1:f1 
   IN_CCO
   (p14:sp7 ph20):f2
   IN_CCO
   5u pl2:f2
   5u
   (p3 ph6:r):f2
;-------------------------------------------- z-filter  
   10u do:f1
   10u fq=cnst16(bf ppm):f2
   10u
   10u pl14:f2 
   GRADIENT3
;-------------------------------------------- semi-ct inept 13co15n  
   (p7 ph5):f2
   d8
   (p16:sp2 ph20):f2
   5u 
   d11 pl14:f2
   GRADIENT8
   (p6 ph20):f3 
   d13
   (p8 ph20):f2
   5u
   GRADIENT8
   d15
   (p16:sp2 ph20):f2
   5u 
   5u pl14:f2
   (p7 ph20):f2
;-------------------------------------------- z filter
   GRADIENT4
   10u pl14:f2
   10u cpds1:f1
;-----------------------------------------N-evolution, INEPT N -> HzNz
   (p5 ph11):f3
   d30
   (p6 ph20):f3
   d29
   (p8 ph20):f2
   (d31 5u do 5u pl1):f1 (d28 p16:sp2 ph20):f2 (d21):f3
   (p5 ph20):f3
;-----------------------------------------z-Filter
   GRADIENT5
;-----------------------------------------INEPT NzHz -> H
   (p1 ph20):f1
   GRADIENT6
   INEPT_W
   (p1*0.2308 ph21 d22 p1*0.6923 ph21 d22 p1*1.4615 ph21):f1 
   (WG_1 p6 ph20 WG_1):f3
   (p1*1.4615 ph23 d22 p1*0.6923 ph23 d22 p1*0.2308 ph23):f1 
   GRADIENT6
   INEPT_W pl13:f3 LOCKH_OFF
;-------------------------------------------- acquisition
   go=2 ph31 cpds3:f3
#ifdef Pv
   1m do:f3 wr #0 if #0 zd ip1
#endif
#ifdef Pw
   1m do:f3 wr #0 if #0 zd ip2
#endif
#ifdef Px
   1m do:f3 wr #0 if #0 zd ip5
#endif
#ifdef Py
   1m do:f3 wr #0 if #0 zd dp11
#endif
   lo to LBLSTS1 times 2
   1m id19
   1m id16
   1m dd17
   1m id20
   1m id26
   1m dd27
   1m id8
   1m id13
   1m dd15
   1m id21
   1m id29
   1m dd30
   1m id31
   lo to LBLF1 times ST1CNT
   10u do:f1
   10u do:f3
   10u do:f2
   10m LOCKH_OFF
   exit

;-------------------------Phases

;-------------------phases for phasecycle

ph8=1 1 3 3

ph6=0                ;phase to correct for CO frequency shift

;-------------------fixed phases

ph20=0
ph21=1
ph22=2
ph23=3

;-------------------phases for States-TPPI

ph31=0 2 2 0

ph1=0
ph2=0
ph5=0 2
ph11=0